Ideone.com

download

copy

using fandoc
using compilerDoc
 
class Main {
	Void main() {
		tellMeAbout := "maps"
 
		index := IndexBuilder().indexAll.buildIndex
		index.tellMeAbout(tellMeAbout).join("\n\n" + "".padl(80, '-')) { it.toPlainText(120) } { echo(it) }
	}
}
 
const class Index {
	internal const Str:Section[]	sections
 
	new make(|This| f) { f(this) }
 
	Section[] tellMeAbout(Str keyword) {
		if (keyword.contains(" "))
			throw ArgErr("Keywords can not contain whitespace! $keyword")
 
		secs	:= (Section[]) (sections[keyword] ?: Section[,]).rw		
		stemmed := SectionBuilder.stem(keyword)
		if (stemmed != keyword)
			secs.addAll(sections[stemmed] ?: Section#.emptyList)
 
		sortScore := |Section s->Int| { (s.parents.size * 2) + s.keywords.size + (s.isApi ? 10 : 0) }
		secs = secs.rw.sort |s1, s2| { sortScore(s1) <=> sortScore(s2) }
		return secs
	}	
}
 
class IndexBuilder {
	private DocEnv docEnv	:= DefaultDocEnv()
	Section[]	sections	:= Section[,]
 
	Index buildIndex() {
		keywords := sections.map { it.keywords }.flatten.unique.sort
 
		sections := Str:Section[][:]
		keywords.each |keyword| {
			sections[keyword] = this.sections.findAll { it.containsKeyword(keyword) }
		}
		return Index {
			it.sections = sections 
		}
	}
 
	This indexAll() {
		Env.cur.findAllPodNames.each { indexPod(it) }
		return this
	}
 
	This indexPod(Str podName) {
		podFile := Env.cur.findPodFile(podName)
		docPod	:= DocPod.load(docEnv, podFile)
		podSec	:= SectionBuilder(docPod)
		sections.add(podSec.toSection)
 
		indexDocs(podName, podSec)
		indexTypes(docPod, podSec)
		return this
	}
 
	This indexFandoc(Str pod, Str type, InStream in) {
		doIndexFandoc(pod, type, in, null).map { it.toSection }
		return this
	}
 
	private Void indexTypes(DocPod docPod, SectionBuilder podSec) {
		docPod.types.each |DocType type| {
			typeSec  := SectionBuilder.makeType(type) { it.parents.push(podSec) }
 
			secs := (SectionBuilder[]) type.slots.map {
				SectionBuilder.makeSlot(it)
			}
			secs.each { it.parents.push(typeSec).push(podSec) }
 
			sections.add(typeSec.toSection)
			sections.addAll(secs.map { it.toSection })
		}
	}
 
	private Void indexDocs(Str podName, SectionBuilder podSec) {
		podFile := Env.cur.findPodFile(podName)
		Zip.open(podFile).contents.findAll |file, uri| { uri.ext == "fandoc" && uri.path[0] == "doc" }.each |File fandocFile| {
			typeSec  := SectionBuilder.makeChapter(podName, fandocFile.basename) { it.parents.push(podSec) }
 
			secs := doIndexFandoc(podName, fandocFile.basename, fandocFile.in, typeSec)
			secs.each { it.parents.push(typeSec).push(podSec) }
 
			sections.add(typeSec.toSection)
			sections.addAll(secs.map { it.toSection })
		}
	}	
 
	private SectionBuilder[] doIndexFandoc(Str pod, Str type, InStream in, SectionBuilder? parent) {
		doc := FandocParser().parse("${pod}::${type}", in, true)
 
		overview := false
		bobs := SectionBuilder[,]
		// for now, ignore headings that are buried in lists
		doc.children.each |elem| {
			if (elem is Heading) {
				if (parent != null && bobs.isEmpty && (elem as Heading).title == "Overview")
					overview = true
				else
					bobs.add(SectionBuilder.makeDoc(pod, type, elem, bobs, overview))
 
			} else {
				// ? 'cos not all fandocs start with a heading!
				if (bobs.isEmpty)
					parent?.addContent(elem)
				else
					bobs.last.addContent(elem)
			}
		}
		return bobs
	}	
}
 
const class Section {
	const Str		what
	const Str		pod
	const Str?		type
	const Str		title
	const Str		content
	const Bool		isApi
	const Bool		isDoc
	const Str[]		keywords
	const Str		fanUrl
	const Uri		webUrl
	const Section[]	parents
 
	new make(|This| f) {
		f(this)
 
		// TODO add acronyms
		keywords = keywords.map { it.lower }
	}
 
	internal Bool containsKeyword(Str keyword) {
		keywords.contains(keyword)
	}
 
	Str toPlainText(Int maxWidth := 80) {
		lev := 0
		text := "\n\n(${what})\n${webUrl}\n\n"
		parents.dup.insert(0, this).eachr {
			text += "".justl(lev * 2)
			text += "${it.title}\n"; lev++
		}
		text += "\n" + content
		return "\n\n" + TextWrapper { normaliseWhitespace = false }.wrap(text, maxWidth)
	}
 
	@NoDoc
	override Str toStr() { fanUrl }
}
 
class SectionBuilder {
	static const Uri	webBaseUrl	:= `http://f...content-available-to-author-only...m.org/doc/`
	Str					fanUrl
	Uri					webUrl
	Str					what
	Str					pod
	Str?				type
	Str					title
	Str?				fandoc
	Bool				isApi
	Str[]				keywords
	Heading? 			heading
	DocNode[]?			content
	SectionBuilder[]	parents		:= SectionBuilder[,]
	Section?			section
 
	new makePod(DocPod pod) {
		this.what		= "Pod"
		this.pod		= pod.name
		this.title		= pod.name
		this.fandoc		= pod.summary
		this.fanUrl		= "${pod.name}::index"
		this.webUrl		= webBaseUrl + `${pod.name}/index`
		this.keywords	= [pod.name]
	}
 
	new makeType(DocType type) {
		this.what		= "Type"
		this.pod		= type.pod.name
		this.type		= type.name
		this.title		= type.name
		this.fanUrl		= "${this.pod}::${this.type}"
		this.webUrl		= webBaseUrl + `${this.pod}/${this.type}`
		this.fandoc		= type.doc.text
		this.keywords	= [type.name]
		this.isApi		= true
	}
 
	new makeSlot(DocSlot slot) {
		this.what		= "Slot"
		this.pod		= slot.parent.pod
		this.type		= slot.parent.name
		this.title		= slot.name
		this.fanUrl		= "${this.pod}::${this.type}.${slot.name}"
		this.webUrl		= webBaseUrl + `${this.pod}/${this.type}#${slot.name}`
		this.fandoc		= slot.doc.text
		this.keywords	= [slot.name]
		this.isApi		= true
 
		field := slot as DocField
		if (field != null) {
			this.what = "Field"
			if (field.init != null)
				title += " := ${field.init}"
		}
 
		method := slot as DocMethod
		if (method != null) {
			this.what = "Method"
			title += "(" + method.params.join(", ") { it.toStr } + ")"
		}
	}
 
	new makeChapter(Str pod, Str type) {
		this.what 			= "Documentation"
		if (type == "pod") {
			this.pod		= pod
			this.type		= "pod-doc"
			this.title		= "pod-doc"
			this.fanUrl		= "${pod}::index"
			this.webUrl		= webBaseUrl + `${pod}/index`
			this.content	= DocNode[,]
			this.keywords	= [pod]
 
		} else {
			this.pod		= pod
			this.type		= type
			this.title		= type
			this.fanUrl		= "${pod}::${type}"
			this.webUrl		= webBaseUrl + `${pod}/${type}`
			this.content	= DocNode[,]
			this.keywords	= type.toDisplayName.split.map { stem(it) }
		}
	}
 
	new makeDoc(Str pod, Str type, Heading heading, SectionBuilder[] bobs, Bool overview) {
		this.what 		= "Documentation"
		this.pod		= pod
		this.type		= type
		this.heading 	= heading
		this.fanUrl		= "${pod}::${type}#${heading.anchorId}"
		this.webUrl		= webBaseUrl + `${pod}/${type}#${heading.anchorId}`
		this.content	= DocNode[,]
 
		levs := Int[1]
		lev  := heading.level
		bobs.eachr |sec| {
			if (sec.heading.level == lev)
				levs.push(levs.pop.increment)
			if (sec.heading.level < lev) {
				levs.push(1)
				lev = sec.heading.level
				parents.push(sec)
			}
		}
		// cater for missing out 'Overview' sections
		if (overview)
			levs.push(levs.pop.increment)
 
		chapter := Version(levs.reverse)		
		this.title = "${chapter}. ${heading.title}"
 
		this.keywords = heading.title.toDisplayName.split.map { stem(it) }
			.exclude |Str key->Bool| { key.size < 2 || key.endsWith("-") }	// remove nonsense
			.exclude |Str key->Bool| { ["and", "or", "the"].contains(key) }	// remove stopwords
	}
 
	// TODO proper stemming!
	static Str stem(Str word) {
		// classes -> class, closures -> closure!!!??
		if (word.endsWith("ses"))
			word = word[0..<-2]
		// pods -> pod, this -> this, class -> class
		if (word.endsWith("s") && !word.endsWith("is") && !word.endsWith("ss"))
			word = word[0..<-1]
		return word		
	}
 
	Void addContent(DocNode node) {
		content.add(node)
	}
 
	Section toSection() {
		if (fandoc == null) {
			buf := Buf()
			out := FandocDocWriter(buf.out)
			content.each { it.write(out) }
			fandoc = buf.flip.readAllStr
		}
 
		return section = Section {
			it.what		= this.what
			it.pod		= this.pod
			it.type		= this.type
			it.title	= this.title
			it.isApi	= this.isApi
			it.isDoc	= this.isApi.not
			it.keywords	= this.keywords
			it.content	= fandoc
			it.fanUrl	= this.fanUrl
			it.webUrl	= this.webUrl
			it.parents	= this.parents.map { it.section }.exclude { it == null }
		}
	}
 
	override Str toStr() { fanUrl }
}
 
** Utility class for pretty-printing text. 
** 
** Example:
** 
** pre>
** text := TextWrapper().wrap("Chuck Norris once ordered a Big Mac at Burger King, and got one.", 25)
** 
** // --> Chuck Norris once ordered
**        a Big Mac at Burger King,
**        and got one.
** 
** <pre 
const class TextWrapper {
 
	** If 'true', then the text is trimmed.
	const Bool trim					:= true
 
	** If 'true', then each run of whitespace (including tabs and new lines) is replaced with a single space character.
	const Bool normaliseWhitespace	:= true
 
    ** If 'true', then words longer than 'maxWidth' will be broken in order to ensure that no line 
    ** is longer than 'maxWidth'. 
    ** 
    ** If 'false', then long words will not be broken and some lines may be longer than 'maxWidth'. 
    ** (Long words will be put on a line by themselves, in order to minimise the amount by which 
    ** 'maxWidth' is exceeded.)
	const Bool breakLongWords		:= true
 
    ** If 'true', wrapping will occur on whitespace and after hyphens in compound words.
	const Bool breakOnHyphens		:= true
 
	** Standard it-block ctor for setting field values.
	** 
	**   syntax: fantom
	**   iceT := TextWrapper {
	**       it.breakLongWords = false
	**   }
	new make(|This|? f := null) { f?.call(this) }
 
	** Formats and word wraps the given text. 
	Str wrap(Str text, Int maxWidth) {
		if (trim)
			text = text.trim
 
		if (normaliseWhitespace) {
			chrs := Int[,]
			spce := false
			text.each |ch| {
				if (ch.isSpace) {
					if (!spce)
						chrs.add(' ')
					spce = true
				} else {
					spce = false
					chrs.add(ch)
				}
			}
			text = Str.fromChars(chrs)
		}
 
		buff := StrBuf()
		line := StrBuf()
		word := StrBuf()
 
		flushLine := |->| {
			if (!normaliseWhitespace || line.toStr.trimEnd.size > 0) {
				buff.join(line.toStr.trimEnd, "\n")
				line.clear
			}
		}
 
		flushWord := |Str char| {
			if (word.size + char.size > 0) {
				if (line.size + (word.toStr + char).trim.size > maxWidth)
					flushLine()
 
				if (word.size > maxWidth && breakLongWords) {
					flushLine()
					while (word.size > maxWidth) {
						part := word.getRange(0..<maxWidth)
						buff.join(part, "\n")
						word.removeRange(0..<maxWidth)
					}
				}
 
				line.add(word.toStr)
				word.clear
 
				if (char == "\n")
					flushLine()
				else
					line.add(char)
			}
		}
 
		text.each |char| {
			if (char.isSpace || (breakOnHyphens && char == '-'))
				flushWord(char.toChar)
			else
				word.addChar(char)
		}
 
		flushWord("")
		flushLine()
 
		return buff.toStr
	}
}

dXNpbmcgZmFuZG9jCnVzaW5nIGNvbXBpbGVyRG9jCgpjbGFzcyBNYWluIHsKCVZvaWQgbWFpbigpIHsKCQl0ZWxsTWVBYm91dCA6PSAibWFwcyIKCQkKCQlpbmRleCA6PSBJbmRleEJ1aWxkZXIoKS5pbmRleEFsbC5idWlsZEluZGV4CgkJaW5kZXgudGVsbE1lQWJvdXQodGVsbE1lQWJvdXQpLmpvaW4oIlxuXG4iICsgIiIucGFkbCg4MCwgJy0nKSkgeyBpdC50b1BsYWluVGV4dCgxMjApIH0geyBlY2hvKGl0KSB9Cgl9Cn0KCmNvbnN0IGNsYXNzIEluZGV4IHsKCWludGVybmFsIGNvbnN0IFN0cjpTZWN0aW9uW10Jc2VjdGlvbnMKCQoJbmV3IG1ha2UofFRoaXN8IGYpIHsgZih0aGlzKSB9CgoJU2VjdGlvbltdIHRlbGxNZUFib3V0KFN0ciBrZXl3b3JkKSB7CgkJaWYgKGtleXdvcmQuY29udGFpbnMoIiAiKSkKCQkJdGhyb3cgQXJnRXJyKCJLZXl3b3JkcyBjYW4gbm90IGNvbnRhaW4gd2hpdGVzcGFjZSEgJGtleXdvcmQiKQoJCQoJCXNlY3MJOj0gKFNlY3Rpb25bXSkgKHNlY3Rpb25zW2tleXdvcmRdID86IFNlY3Rpb25bLF0pLnJ3CQkKCQlzdGVtbWVkIDo9IFNlY3Rpb25CdWlsZGVyLnN0ZW0oa2V5d29yZCkKCQlpZiAoc3RlbW1lZCAhPSBrZXl3b3JkKQoJCQlzZWNzLmFkZEFsbChzZWN0aW9uc1tzdGVtbWVkXSA/OiBTZWN0aW9uIy5lbXB0eUxpc3QpCgoJCXNvcnRTY29yZSA6PSB8U2VjdGlvbiBzLT5JbnR8IHsgKHMucGFyZW50cy5zaXplICogMikgKyBzLmtleXdvcmRzLnNpemUgKyAocy5pc0FwaSA/IDEwIDogMCkgfQoJCXNlY3MgPSBzZWNzLnJ3LnNvcnQgfHMxLCBzMnwgeyBzb3J0U2NvcmUoczEpIDw9PiBzb3J0U2NvcmUoczIpIH0KCQlyZXR1cm4gc2VjcwoJfQkKfQoKY2xhc3MgSW5kZXhCdWlsZGVyIHsKCXByaXZhdGUgRG9jRW52IGRvY0Vudgk6PSBEZWZhdWx0RG9jRW52KCkKCVNlY3Rpb25bXQlzZWN0aW9ucwk6PSBTZWN0aW9uWyxdCgkKCUluZGV4IGJ1aWxkSW5kZXgoKSB7CgkJa2V5d29yZHMgOj0gc2VjdGlvbnMubWFwIHsgaXQua2V5d29yZHMgfS5mbGF0dGVuLnVuaXF1ZS5zb3J0CgkJCQkKCQlzZWN0aW9ucyA6PSBTdHI6U2VjdGlvbltdWzpdCgkJa2V5d29yZHMuZWFjaCB8a2V5d29yZHwgewoJCQlzZWN0aW9uc1trZXl3b3JkXSA9IHRoaXMuc2VjdGlvbnMuZmluZEFsbCB7IGl0LmNvbnRhaW5zS2V5d29yZChrZXl3b3JkKSB9CgkJfQoJCXJldHVybiBJbmRleCB7CgkJCWl0LnNlY3Rpb25zID0gc2VjdGlvbnMgCgkJfQoJfQoKCVRoaXMgaW5kZXhBbGwoKSB7CgkJRW52LmN1ci5maW5kQWxsUG9kTmFtZXMuZWFjaCB7IGluZGV4UG9kKGl0KSB9CgkJcmV0dXJuIHRoaXMKCX0KCQoJVGhpcyBpbmRleFBvZChTdHIgcG9kTmFtZSkgewoJCXBvZEZpbGUgOj0gRW52LmN1ci5maW5kUG9kRmlsZShwb2ROYW1lKQoJCWRvY1BvZAk6PSBEb2NQb2QubG9hZChkb2NFbnYsIHBvZEZpbGUpCgkJcG9kU2VjCTo9IFNlY3Rpb25CdWlsZGVyKGRvY1BvZCkKCQlzZWN0aW9ucy5hZGQocG9kU2VjLnRvU2VjdGlvbikKCgkJaW5kZXhEb2NzKHBvZE5hbWUsIHBvZFNlYykKCQlpbmRleFR5cGVzKGRvY1BvZCwgcG9kU2VjKQoJCXJldHVybiB0aGlzCgl9CgoJVGhpcyBpbmRleEZhbmRvYyhTdHIgcG9kLCBTdHIgdHlwZSwgSW5TdHJlYW0gaW4pIHsKCQlkb0luZGV4RmFuZG9jKHBvZCwgdHlwZSwgaW4sIG51bGwpLm1hcCB7IGl0LnRvU2VjdGlvbiB9CgkJcmV0dXJuIHRoaXMKCX0KCglwcml2YXRlIFZvaWQgaW5kZXhUeXBlcyhEb2NQb2QgZG9jUG9kLCBTZWN0aW9uQnVpbGRlciBwb2RTZWMpIHsKCQlkb2NQb2QudHlwZXMuZWFjaCB8RG9jVHlwZSB0eXBlfCB7CgkJCXR5cGVTZWMgIDo9IFNlY3Rpb25CdWlsZGVyLm1ha2VUeXBlKHR5cGUpIHsgaXQucGFyZW50cy5wdXNoKHBvZFNlYykgfQoKCQkJc2VjcyA6PSAoU2VjdGlvbkJ1aWxkZXJbXSkgdHlwZS5zbG90cy5tYXAgewoJCQkJU2VjdGlvbkJ1aWxkZXIubWFrZVNsb3QoaXQpCgkJCX0KCQkJc2Vjcy5lYWNoIHsgaXQucGFyZW50cy5wdXNoKHR5cGVTZWMpLnB1c2gocG9kU2VjKSB9CgoJCQlzZWN0aW9ucy5hZGQodHlwZVNlYy50b1NlY3Rpb24pCgkJCXNlY3Rpb25zLmFkZEFsbChzZWNzLm1hcCB7IGl0LnRvU2VjdGlvbiB9KQoJCX0KCX0KCQoJcHJpdmF0ZSBWb2lkIGluZGV4RG9jcyhTdHIgcG9kTmFtZSwgU2VjdGlvbkJ1aWxkZXIgcG9kU2VjKSB7CgkJcG9kRmlsZSA6PSBFbnYuY3VyLmZpbmRQb2RGaWxlKHBvZE5hbWUpCgkJWmlwLm9wZW4ocG9kRmlsZSkuY29udGVudHMuZmluZEFsbCB8ZmlsZSwgdXJpfCB7IHVyaS5leHQgPT0gImZhbmRvYyIgJiYgdXJpLnBhdGhbMF0gPT0gImRvYyIgfS5lYWNoIHxGaWxlIGZhbmRvY0ZpbGV8IHsKCQkJdHlwZVNlYyAgOj0gU2VjdGlvbkJ1aWxkZXIubWFrZUNoYXB0ZXIocG9kTmFtZSwgZmFuZG9jRmlsZS5iYXNlbmFtZSkgeyBpdC5wYXJlbnRzLnB1c2gocG9kU2VjKSB9CgoJCQlzZWNzIDo9IGRvSW5kZXhGYW5kb2MocG9kTmFtZSwgZmFuZG9jRmlsZS5iYXNlbmFtZSwgZmFuZG9jRmlsZS5pbiwgdHlwZVNlYykKCQkJc2Vjcy5lYWNoIHsgaXQucGFyZW50cy5wdXNoKHR5cGVTZWMpLnB1c2gocG9kU2VjKSB9CgoJCQlzZWN0aW9ucy5hZGQodHlwZVNlYy50b1NlY3Rpb24pCgkJCXNlY3Rpb25zLmFkZEFsbChzZWNzLm1hcCB7IGl0LnRvU2VjdGlvbiB9KQoJCX0KCX0JCgoJcHJpdmF0ZSBTZWN0aW9uQnVpbGRlcltdIGRvSW5kZXhGYW5kb2MoU3RyIHBvZCwgU3RyIHR5cGUsIEluU3RyZWFtIGluLCBTZWN0aW9uQnVpbGRlcj8gcGFyZW50KSB7CgkJZG9jIDo9IEZhbmRvY1BhcnNlcigpLnBhcnNlKCIke3BvZH06OiR7dHlwZX0iLCBpbiwgdHJ1ZSkKCQkKCQlvdmVydmlldyA6PSBmYWxzZQoJCWJvYnMgOj0gU2VjdGlvbkJ1aWxkZXJbLF0KCQkvLyBmb3Igbm93LCBpZ25vcmUgaGVhZGluZ3MgdGhhdCBhcmUgYnVyaWVkIGluIGxpc3RzCgkJZG9jLmNoaWxkcmVuLmVhY2ggfGVsZW18IHsKCQkJaWYgKGVsZW0gaXMgSGVhZGluZykgewoJCQkJaWYgKHBhcmVudCAhPSBudWxsICYmIGJvYnMuaXNFbXB0eSAmJiAoZWxlbSBhcyBIZWFkaW5nKS50aXRsZSA9PSAiT3ZlcnZpZXciKQoJCQkJCW92ZXJ2aWV3ID0gdHJ1ZQoJCQkJZWxzZQoJCQkJCWJvYnMuYWRkKFNlY3Rpb25CdWlsZGVyLm1ha2VEb2MocG9kLCB0eXBlLCBlbGVtLCBib2JzLCBvdmVydmlldykpCgkJCQkKCQkJfSBlbHNlIHsKCQkJCS8vID8gJ2NvcyBub3QgYWxsIGZhbmRvY3Mgc3RhcnQgd2l0aCBhIGhlYWRpbmchCgkJCQlpZiAoYm9icy5pc0VtcHR5KQoJCQkJCXBhcmVudD8uYWRkQ29udGVudChlbGVtKQoJCQkJZWxzZQoJCQkJCWJvYnMubGFzdC5hZGRDb250ZW50KGVsZW0pCgkJCX0KCQl9CgkJcmV0dXJuIGJvYnMKCX0JCn0KCmNvbnN0IGNsYXNzIFNlY3Rpb24gewoJY29uc3QgU3RyCQl3aGF0Cgljb25zdCBTdHIJCXBvZAoJY29uc3QgU3RyPwkJdHlwZQoJY29uc3QgU3RyCQl0aXRsZQoJY29uc3QgU3RyCQljb250ZW50Cgljb25zdCBCb29sCQlpc0FwaQoJY29uc3QgQm9vbAkJaXNEb2MKCWNvbnN0IFN0cltdCQlrZXl3b3JkcwoJY29uc3QgU3RyCQlmYW5VcmwKCWNvbnN0IFVyaQkJd2ViVXJsCgljb25zdCBTZWN0aW9uW10JcGFyZW50cwoKCW5ldyBtYWtlKHxUaGlzfCBmKSB7CgkJZih0aGlzKQoJCQoJCS8vIFRPRE8gYWRkIGFjcm9ueW1zCgkJa2V5d29yZHMgPSBrZXl3b3Jkcy5tYXAgeyBpdC5sb3dlciB9Cgl9CgoJaW50ZXJuYWwgQm9vbCBjb250YWluc0tleXdvcmQoU3RyIGtleXdvcmQpIHsKCQlrZXl3b3Jkcy5jb250YWlucyhrZXl3b3JkKQoJfQoKCVN0ciB0b1BsYWluVGV4dChJbnQgbWF4V2lkdGggOj0gODApIHsKCQlsZXYgOj0gMAoJCXRleHQgOj0gIlxuXG4oJHt3aGF0fSlcbiR7d2ViVXJsfVxuXG4iCgkJcGFyZW50cy5kdXAuaW5zZXJ0KDAsIHRoaXMpLmVhY2hyIHsKCQkJdGV4dCArPSAiIi5qdXN0bChsZXYgKiAyKQoJCQl0ZXh0ICs9ICIke2l0LnRpdGxlfVxuIjsgbGV2KysKCQl9CgkJdGV4dCArPSAiXG4iICsgY29udGVudAoJCXJldHVybiAiXG5cbiIgKyBUZXh0V3JhcHBlciB7IG5vcm1hbGlzZVdoaXRlc3BhY2UgPSBmYWxzZSB9LndyYXAodGV4dCwgbWF4V2lkdGgpCgl9CgkKCUBOb0RvYwoJb3ZlcnJpZGUgU3RyIHRvU3RyKCkgeyBmYW5VcmwgfQp9CgpjbGFzcyBTZWN0aW9uQnVpbGRlciB7CglzdGF0aWMgY29uc3QgVXJpCXdlYkJhc2VVcmwJOj0gYGh0dHA6Ly9mLi4uY29udGVudC1hdmFpbGFibGUtdG8tYXV0aG9yLW9ubHkuLi5tLm9yZy9kb2MvYAoJU3RyCQkJCQlmYW5VcmwKCVVyaQkJCQkJd2ViVXJsCglTdHIJCQkJCXdoYXQKCVN0cgkJCQkJcG9kCglTdHI/CQkJCXR5cGUKCVN0cgkJCQkJdGl0bGUKCVN0cj8JCQkJZmFuZG9jCglCb29sCQkJCWlzQXBpCglTdHJbXQkJCQlrZXl3b3JkcwoJSGVhZGluZz8gCQkJaGVhZGluZwoJRG9jTm9kZVtdPwkJCWNvbnRlbnQKCVNlY3Rpb25CdWlsZGVyW10JcGFyZW50cwkJOj0gU2VjdGlvbkJ1aWxkZXJbLF0KCVNlY3Rpb24/CQkJc2VjdGlvbgoJCgluZXcgbWFrZVBvZChEb2NQb2QgcG9kKSB7CgkJdGhpcy53aGF0CQk9ICJQb2QiCgkJdGhpcy5wb2QJCT0gcG9kLm5hbWUKCQl0aGlzLnRpdGxlCQk9IHBvZC5uYW1lCgkJdGhpcy5mYW5kb2MJCT0gcG9kLnN1bW1hcnkKCQl0aGlzLmZhblVybAkJPSAiJHtwb2QubmFtZX06OmluZGV4IgoJCXRoaXMud2ViVXJsCQk9IHdlYkJhc2VVcmwgKyBgJHtwb2QubmFtZX0vaW5kZXhgCgkJdGhpcy5rZXl3b3Jkcwk9IFtwb2QubmFtZV0KCX0KCQoJbmV3IG1ha2VUeXBlKERvY1R5cGUgdHlwZSkgewoJCXRoaXMud2hhdAkJPSAiVHlwZSIKCQl0aGlzLnBvZAkJPSB0eXBlLnBvZC5uYW1lCgkJdGhpcy50eXBlCQk9IHR5cGUubmFtZQoJCXRoaXMudGl0bGUJCT0gdHlwZS5uYW1lCgkJdGhpcy5mYW5VcmwJCT0gIiR7dGhpcy5wb2R9Ojoke3RoaXMudHlwZX0iCgkJdGhpcy53ZWJVcmwJCT0gd2ViQmFzZVVybCArIGAke3RoaXMucG9kfS8ke3RoaXMudHlwZX1gCgkJdGhpcy5mYW5kb2MJCT0gdHlwZS5kb2MudGV4dAoJCXRoaXMua2V5d29yZHMJPSBbdHlwZS5uYW1lXQoJCXRoaXMuaXNBcGkJCT0gdHJ1ZQoJfQoJCgluZXcgbWFrZVNsb3QoRG9jU2xvdCBzbG90KSB7CgkJdGhpcy53aGF0CQk9ICJTbG90IgoJCXRoaXMucG9kCQk9IHNsb3QucGFyZW50LnBvZAoJCXRoaXMudHlwZQkJPSBzbG90LnBhcmVudC5uYW1lCgkJdGhpcy50aXRsZQkJPSBzbG90Lm5hbWUKCQl0aGlzLmZhblVybAkJPSAiJHt0aGlzLnBvZH06OiR7dGhpcy50eXBlfS4ke3Nsb3QubmFtZX0iCgkJdGhpcy53ZWJVcmwJCT0gd2ViQmFzZVVybCArIGAke3RoaXMucG9kfS8ke3RoaXMudHlwZX0jJHtzbG90Lm5hbWV9YAoJCXRoaXMuZmFuZG9jCQk9IHNsb3QuZG9jLnRleHQKCQl0aGlzLmtleXdvcmRzCT0gW3Nsb3QubmFtZV0KCQl0aGlzLmlzQXBpCQk9IHRydWUKCQkKCQlmaWVsZCA6PSBzbG90IGFzIERvY0ZpZWxkCgkJaWYgKGZpZWxkICE9IG51bGwpIHsKCQkJdGhpcy53aGF0ID0gIkZpZWxkIgoJCQlpZiAoZmllbGQuaW5pdCAhPSBudWxsKQoJCQkJdGl0bGUgKz0gIiA6PSAke2ZpZWxkLmluaXR9IgoJCX0KCgkJbWV0aG9kIDo9IHNsb3QgYXMgRG9jTWV0aG9kCgkJaWYgKG1ldGhvZCAhPSBudWxsKSB7CgkJCXRoaXMud2hhdCA9ICJNZXRob2QiCgkJCXRpdGxlICs9ICIoIiArIG1ldGhvZC5wYXJhbXMuam9pbigiLCAiKSB7IGl0LnRvU3RyIH0gKyAiKSIKCQl9Cgl9CgkKCW5ldyBtYWtlQ2hhcHRlcihTdHIgcG9kLCBTdHIgdHlwZSkgewoJCXRoaXMud2hhdCAJCQk9ICJEb2N1bWVudGF0aW9uIgoJCWlmICh0eXBlID09ICJwb2QiKSB7CgkJCXRoaXMucG9kCQk9IHBvZAoJCQl0aGlzLnR5cGUJCT0gInBvZC1kb2MiCgkJCXRoaXMudGl0bGUJCT0gInBvZC1kb2MiCgkJCXRoaXMuZmFuVXJsCQk9ICIke3BvZH06OmluZGV4IgoJCQl0aGlzLndlYlVybAkJPSB3ZWJCYXNlVXJsICsgYCR7cG9kfS9pbmRleGAKCQkJdGhpcy5jb250ZW50CT0gRG9jTm9kZVssXQoJCQl0aGlzLmtleXdvcmRzCT0gW3BvZF0KCQkJCgkJfSBlbHNlIHsKCQkJdGhpcy5wb2QJCT0gcG9kCgkJCXRoaXMudHlwZQkJPSB0eXBlCgkJCXRoaXMudGl0bGUJCT0gdHlwZQoJCQl0aGlzLmZhblVybAkJPSAiJHtwb2R9Ojoke3R5cGV9IgoJCQl0aGlzLndlYlVybAkJPSB3ZWJCYXNlVXJsICsgYCR7cG9kfS8ke3R5cGV9YAoJCQl0aGlzLmNvbnRlbnQJPSBEb2NOb2RlWyxdCgkJCXRoaXMua2V5d29yZHMJPSB0eXBlLnRvRGlzcGxheU5hbWUuc3BsaXQubWFwIHsgc3RlbShpdCkgfQoJCX0KCX0KCgluZXcgbWFrZURvYyhTdHIgcG9kLCBTdHIgdHlwZSwgSGVhZGluZyBoZWFkaW5nLCBTZWN0aW9uQnVpbGRlcltdIGJvYnMsIEJvb2wgb3ZlcnZpZXcpIHsKCQl0aGlzLndoYXQgCQk9ICJEb2N1bWVudGF0aW9uIgoJCXRoaXMucG9kCQk9IHBvZAoJCXRoaXMudHlwZQkJPSB0eXBlCgkJdGhpcy5oZWFkaW5nIAk9IGhlYWRpbmcKCQl0aGlzLmZhblVybAkJPSAiJHtwb2R9Ojoke3R5cGV9IyR7aGVhZGluZy5hbmNob3JJZH0iCgkJdGhpcy53ZWJVcmwJCT0gd2ViQmFzZVVybCArIGAke3BvZH0vJHt0eXBlfSMke2hlYWRpbmcuYW5jaG9ySWR9YAoJCXRoaXMuY29udGVudAk9IERvY05vZGVbLF0KCgkJbGV2cyA6PSBJbnRbMV0KCQlsZXYgIDo9IGhlYWRpbmcubGV2ZWwKCQlib2JzLmVhY2hyIHxzZWN8IHsKCQkJaWYgKHNlYy5oZWFkaW5nLmxldmVsID09IGxldikKCQkJCWxldnMucHVzaChsZXZzLnBvcC5pbmNyZW1lbnQpCgkJCWlmIChzZWMuaGVhZGluZy5sZXZlbCA8IGxldikgewoJCQkJbGV2cy5wdXNoKDEpCgkJCQlsZXYgPSBzZWMuaGVhZGluZy5sZXZlbAoJCQkJcGFyZW50cy5wdXNoKHNlYykKCQkJfQoJCX0KCQkvLyBjYXRlciBmb3IgbWlzc2luZyBvdXQgJ092ZXJ2aWV3JyBzZWN0aW9ucwoJCWlmIChvdmVydmlldykKCQkJbGV2cy5wdXNoKGxldnMucG9wLmluY3JlbWVudCkKCQkKCQljaGFwdGVyIDo9IFZlcnNpb24obGV2cy5yZXZlcnNlKQkJCgkJdGhpcy50aXRsZSA9ICIke2NoYXB0ZXJ9LiAke2hlYWRpbmcudGl0bGV9IgoKCQl0aGlzLmtleXdvcmRzID0gaGVhZGluZy50aXRsZS50b0Rpc3BsYXlOYW1lLnNwbGl0Lm1hcCB7IHN0ZW0oaXQpIH0KCQkJLmV4Y2x1ZGUgfFN0ciBrZXktPkJvb2x8IHsga2V5LnNpemUgPCAyIHx8IGtleS5lbmRzV2l0aCgiLSIpIH0JLy8gcmVtb3ZlIG5vbnNlbnNlCgkJCS5leGNsdWRlIHxTdHIga2V5LT5Cb29sfCB7IFsiYW5kIiwgIm9yIiwgInRoZSJdLmNvbnRhaW5zKGtleSkgfQkvLyByZW1vdmUgc3RvcHdvcmRzCgl9CgkKCS8vIFRPRE8gcHJvcGVyIHN0ZW1taW5nIQoJc3RhdGljIFN0ciBzdGVtKFN0ciB3b3JkKSB7CgkJLy8gY2xhc3NlcyAtPiBjbGFzcywgY2xvc3VyZXMgLT4gY2xvc3VyZSEhIT8/CgkJaWYgKHdvcmQuZW5kc1dpdGgoInNlcyIpKQoJCQl3b3JkID0gd29yZFswLi48LTJdCgkJLy8gcG9kcyAtPiBwb2QsIHRoaXMgLT4gdGhpcywgY2xhc3MgLT4gY2xhc3MKCQlpZiAod29yZC5lbmRzV2l0aCgicyIpICYmICF3b3JkLmVuZHNXaXRoKCJpcyIpICYmICF3b3JkLmVuZHNXaXRoKCJzcyIpKQoJCQl3b3JkID0gd29yZFswLi48LTFdCgkJcmV0dXJuIHdvcmQJCQoJfQoKCVZvaWQgYWRkQ29udGVudChEb2NOb2RlIG5vZGUpIHsKCQljb250ZW50LmFkZChub2RlKQoJfQoJCglTZWN0aW9uIHRvU2VjdGlvbigpIHsKCQlpZiAoZmFuZG9jID09IG51bGwpIHsKCQkJYnVmIDo9IEJ1ZigpCgkJCW91dCA6PSBGYW5kb2NEb2NXcml0ZXIoYnVmLm91dCkKCQkJY29udGVudC5lYWNoIHsgaXQud3JpdGUob3V0KSB9CgkJCWZhbmRvYyA9IGJ1Zi5mbGlwLnJlYWRBbGxTdHIKCQl9CgoJCXJldHVybiBzZWN0aW9uID0gU2VjdGlvbiB7CgkJCWl0LndoYXQJCT0gdGhpcy53aGF0CgkJCWl0LnBvZAkJPSB0aGlzLnBvZAoJCQlpdC50eXBlCQk9IHRoaXMudHlwZQoJCQlpdC50aXRsZQk9IHRoaXMudGl0bGUKCQkJaXQuaXNBcGkJPSB0aGlzLmlzQXBpCgkJCWl0LmlzRG9jCT0gdGhpcy5pc0FwaS5ub3QKCQkJaXQua2V5d29yZHMJPSB0aGlzLmtleXdvcmRzCgkJCWl0LmNvbnRlbnQJPSBmYW5kb2MKCQkJaXQuZmFuVXJsCT0gdGhpcy5mYW5VcmwKCQkJaXQud2ViVXJsCT0gdGhpcy53ZWJVcmwKCQkJaXQucGFyZW50cwk9IHRoaXMucGFyZW50cy5tYXAgeyBpdC5zZWN0aW9uIH0uZXhjbHVkZSB7IGl0ID09IG51bGwgfQoJCX0KCX0KCQoJb3ZlcnJpZGUgU3RyIHRvU3RyKCkgeyBmYW5VcmwgfQp9CgoqKiBVdGlsaXR5IGNsYXNzIGZvciBwcmV0dHktcHJpbnRpbmcgdGV4dC4gCioqIAoqKiBFeGFtcGxlOgoqKiAKKiogcHJlPgoqKiB0ZXh0IDo9IFRleHRXcmFwcGVyKCkud3JhcCgiQ2h1Y2sgTm9ycmlzIG9uY2Ugb3JkZXJlZCBhIEJpZyBNYWMgYXQgQnVyZ2VyIEtpbmcsIGFuZCBnb3Qgb25lLiIsIDI1KQoqKiAKKiogLy8gLS0+IENodWNrIE5vcnJpcyBvbmNlIG9yZGVyZWQKKiogICAgICAgIGEgQmlnIE1hYyBhdCBCdXJnZXIgS2luZywKKiogICAgICAgIGFuZCBnb3Qgb25lLgoqKiAKKiogPHByZSAKY29uc3QgY2xhc3MgVGV4dFdyYXBwZXIgewoKCSoqIElmICd0cnVlJywgdGhlbiB0aGUgdGV4dCBpcyB0cmltbWVkLgoJY29uc3QgQm9vbCB0cmltCQkJCQk6PSB0cnVlCgoJKiogSWYgJ3RydWUnLCB0aGVuIGVhY2ggcnVuIG9mIHdoaXRlc3BhY2UgKGluY2x1ZGluZyB0YWJzIGFuZCBuZXcgbGluZXMpIGlzIHJlcGxhY2VkIHdpdGggYSBzaW5nbGUgc3BhY2UgY2hhcmFjdGVyLgoJY29uc3QgQm9vbCBub3JtYWxpc2VXaGl0ZXNwYWNlCTo9IHRydWUKCQogICAgKiogSWYgJ3RydWUnLCB0aGVuIHdvcmRzIGxvbmdlciB0aGFuICdtYXhXaWR0aCcgd2lsbCBiZSBicm9rZW4gaW4gb3JkZXIgdG8gZW5zdXJlIHRoYXQgbm8gbGluZSAKICAgICoqIGlzIGxvbmdlciB0aGFuICdtYXhXaWR0aCcuIAogICAgKiogCiAgICAqKiBJZiAnZmFsc2UnLCB0aGVuIGxvbmcgd29yZHMgd2lsbCBub3QgYmUgYnJva2VuIGFuZCBzb21lIGxpbmVzIG1heSBiZSBsb25nZXIgdGhhbiAnbWF4V2lkdGgnLiAKICAgICoqIChMb25nIHdvcmRzIHdpbGwgYmUgcHV0IG9uIGEgbGluZSBieSB0aGVtc2VsdmVzLCBpbiBvcmRlciB0byBtaW5pbWlzZSB0aGUgYW1vdW50IGJ5IHdoaWNoIAogICAgKiogJ21heFdpZHRoJyBpcyBleGNlZWRlZC4pCgljb25zdCBCb29sIGJyZWFrTG9uZ1dvcmRzCQk6PSB0cnVlCgogICAgKiogSWYgJ3RydWUnLCB3cmFwcGluZyB3aWxsIG9jY3VyIG9uIHdoaXRlc3BhY2UgYW5kIGFmdGVyIGh5cGhlbnMgaW4gY29tcG91bmQgd29yZHMuCgljb25zdCBCb29sIGJyZWFrT25IeXBoZW5zCQk6PSB0cnVlCgkKCSoqIFN0YW5kYXJkIGl0LWJsb2NrIGN0b3IgZm9yIHNldHRpbmcgZmllbGQgdmFsdWVzLgoJKiogCgkqKiAgIHN5bnRheDogZmFudG9tCgkqKiAgIGljZVQgOj0gVGV4dFdyYXBwZXIgewoJKiogICAgICAgaXQuYnJlYWtMb25nV29yZHMgPSBmYWxzZQoJKiogICB9CgluZXcgbWFrZSh8VGhpc3w/IGYgOj0gbnVsbCkgeyBmPy5jYWxsKHRoaXMpIH0KCgkqKiBGb3JtYXRzIGFuZCB3b3JkIHdyYXBzIHRoZSBnaXZlbiB0ZXh0LiAKCVN0ciB3cmFwKFN0ciB0ZXh0LCBJbnQgbWF4V2lkdGgpIHsKCQlpZiAodHJpbSkKCQkJdGV4dCA9IHRleHQudHJpbQoKCQlpZiAobm9ybWFsaXNlV2hpdGVzcGFjZSkgewoJCQljaHJzIDo9IEludFssXQoJCQlzcGNlIDo9IGZhbHNlCgkJCXRleHQuZWFjaCB8Y2h8IHsKCQkJCWlmIChjaC5pc1NwYWNlKSB7CgkJCQkJaWYgKCFzcGNlKQoJCQkJCQljaHJzLmFkZCgnICcpCgkJCQkJc3BjZSA9IHRydWUKCQkJCX0gZWxzZSB7CgkJCQkJc3BjZSA9IGZhbHNlCgkJCQkJY2hycy5hZGQoY2gpCgkJCQl9CgkJCX0KCQkJdGV4dCA9IFN0ci5mcm9tQ2hhcnMoY2hycykKCQl9CgkJCgkJYnVmZiA6PSBTdHJCdWYoKQoJCWxpbmUgOj0gU3RyQnVmKCkKCQl3b3JkIDo9IFN0ckJ1ZigpCgoJCWZsdXNoTGluZSA6PSB8LT58IHsKCQkJaWYgKCFub3JtYWxpc2VXaGl0ZXNwYWNlIHx8IGxpbmUudG9TdHIudHJpbUVuZC5zaXplID4gMCkgewoJCQkJYnVmZi5qb2luKGxpbmUudG9TdHIudHJpbUVuZCwgIlxuIikKCQkJCWxpbmUuY2xlYXIKCQkJfQoJCX0KCgkJZmx1c2hXb3JkIDo9IHxTdHIgY2hhcnwgewoJCQlpZiAod29yZC5zaXplICsgY2hhci5zaXplID4gMCkgewoJCQkJaWYgKGxpbmUuc2l6ZSArICh3b3JkLnRvU3RyICsgY2hhcikudHJpbS5zaXplID4gbWF4V2lkdGgpCgkJCQkJZmx1c2hMaW5lKCkKCQoJCQkJaWYgKHdvcmQuc2l6ZSA+IG1heFdpZHRoICYmIGJyZWFrTG9uZ1dvcmRzKSB7CgkJCQkJZmx1c2hMaW5lKCkKCQkJCQl3aGlsZSAod29yZC5zaXplID4gbWF4V2lkdGgpIHsKCQkJCQkJcGFydCA6PSB3b3JkLmdldFJhbmdlKDAuLjxtYXhXaWR0aCkKCQkJCQkJYnVmZi5qb2luKHBhcnQsICJcbiIpCgkJCQkJCXdvcmQucmVtb3ZlUmFuZ2UoMC4uPG1heFdpZHRoKQoJCQkJCX0KCQkJCX0KCgkJCQlsaW5lLmFkZCh3b3JkLnRvU3RyKQoJCQkJd29yZC5jbGVhcgoKCQkJCWlmIChjaGFyID09ICJcbiIpCgkJCQkJZmx1c2hMaW5lKCkKCQkJCWVsc2UKCQkJCQlsaW5lLmFkZChjaGFyKQoJCQl9CgkJfQoKCQl0ZXh0LmVhY2ggfGNoYXJ8IHsKCQkJaWYgKGNoYXIuaXNTcGFjZSB8fCAoYnJlYWtPbkh5cGhlbnMgJiYgY2hhciA9PSAnLScpKQoJCQkJZmx1c2hXb3JkKGNoYXIudG9DaGFyKQoJCQllbHNlCgkJCQl3b3JkLmFkZENoYXIoY2hhcikKCQl9CgoJCWZsdXNoV29yZCgiIikKCQlmbHVzaExpbmUoKQoKCQlyZXR1cm4gYnVmZi50b1N0cgoJfQp9Cg==

Success #stdin #stdout 4.31s 2922496KB

stdin

copy

Standard input is empty

stdout

copy


(Documentation)
http://f...content-available-to-author-only...m.org/doc/docLang/Literals#map

docLang
  Literals
    13. Map

The [sys::Map]`sys::Map` class stores a set of key/value pairs using a hash table.  Maps may be instantiated using the
following literal syntax:

  // syntax format where K:V is the optional map type,
  // and the keys and values are arbitrary expressions:
  [V:K][key0:value0, key1:value1, ... keyN:valueN]

  // examples
  [Int:Str][1:"one", 2:"two"]  // map of Strs keyed by Int
  Int:Str[1:"one", 2:"two"]    // same as above with shorthand type syntax
  [1:"one", 2:"two"]           // same as above using type inference
  Int:Str[:]                   // empty Int:Str map
  [:]                          // empty map of Obj:Obj?

The 'Map' literal syntax is like 'List' except we specify the key value pairs using a colon.  The type prefix of a map
literal is any valid [map signature]`TypeSystem#mapSignature`.  If the type prefix is omitted, then type inference is
used to determine the type of the keys and values using the same rules as list literals.  For example:

  [1:"one", 2:"two"]    // evaluates to Int:Str
  [1:"one", 2:null]     // evaluates to Int:Str?
  [1:"one", 2f:"two"]   // evaluates to Num:Str
  [1:"one", 2f:null]    // evaluates to Num:Str?
  [1:"one", 2f:0xabcd]  // evaluates to Num:Obj
  [0:["one"]]           // evaluates to Int:Str[]

The empty map is denoted using the special syntax '[:]' with or without a type prefix.

Note that maps may not be typed with a nullable key.  If you are using type inference, you might need to explicitly type
a map which will store null:

  [1:"one", 2:"two"]           // cannot store null values
  Int:Str?[1:"one", 2:"two"]   // can store null values

The type 'Int:Str?' is a map with 'Int' keys and 'Str?' values.  However the type '[Int:Str]?' is map of 'Int:Str' where
the map variable itself might be null.

If a map literal without an explicit type is used as a field initializer, then it infers its type from the field's
declared type:

  Str:File[] files := [:]   // initial value inferred as Str:File[:]

See [Appendix]`Appendix#typeInference` for the formal rules used for type inference of maps.

--------------------------------------------------------------------------------

(Documentation)
http://f...content-available-to-author-only...m.org/doc/docLang/TypeSystem#map

docLang
  TypeSystem
    9. Collections
      9.2. Map

Maps are a hashmap of key-value pair, very similar to an 'HashMap' or 'Hashtable' in Java or C#.  Maps have a
[literal]`Literals#map` syntax and a special [type signature]`#mapSignature` syntax.

--------------------------------------------------------------------------------

(Documentation)
http://f...content-available-to-author-only...m.org/doc/docLang/TypeSystem#mapSignature

docLang
  TypeSystem
    10. Generics
      10.2. Map Type Signatures

The [sys::Map]`sys::Map` class uses three generic parameters:

- 'K': type of key stored by the map
- 'V': type of value stored by the map
- 'M': type of the parameterized map

The parameterization syntax of 'Map' is designed to mimic the [map literal]`Literals#map` syntax:

  // format
  [K:V]          // formal signature
  K:V            // brackets are optional in most cases

  // examples
  [Str:User]     // map of Users keyed by Str
  Str:User       // same as above without optional brackets
  Uri:File?      // map of File? keyed by Uri
  [Uri:File]?    // map of Uri:File where the entire map variable might be null
  Str:File[]     // map of File[] keyed by Str
  [Str:File][]   // list of Str:File (brackets not optional)

The formal syntax for 'Map' parameterization is '[K:V]'.  Typically the brackets are optional, and by convention left
off.  But in some complicated type declarations you will need to use the brackets such as the '[Str:File][]' example
above.  Brackets are always used in APIs which return formal signatures.

--------------------------------------------------------------------------------

(Type)
http://f...content-available-to-author-only...m.org/doc/sys/Map

sys
  Map

Map is a hash map of key/value pairs.

See [examples]`examples::sys-maps`.

--------------------------------------------------------------------------------

(Method)
http://f...content-available-to-author-only...m.org/doc/compiler/ReflectFacet#map

compiler
  ReflectFacet
    map(compiler::ReflectNamespace ns, sys::Facet? f)

--------------------------------------------------------------------------------

(Method)
http://f...content-available-to-author-only...m.org/doc/sys/List#map

sys
  List
    map(|sys::V,sys::Int->sys::Obj?| c)

Create a new list which is the result of calling c for
every item in this list.  The new list is typed based on
the return type of c.  This method is readonly safe.

Example:
  list := [3, 4, 5]
  list.map |Int v->Int| { return v*2 } => [6, 8, 10]

--------------------------------------------------------------------------------

(Method)
http://f...content-available-to-author-only...m.org/doc/sys/Map#map

sys
  Map
    map(|sys::V,sys::K->sys::Obj?| c)

Create a new map with the same keys, but apply the specified
closure to generate new values.  The new mapped is typed based
on the return type of c.  If this map is `ordered` or
`caseInsensitive`, then the resulting map is too.  This method
is readonly safe.

Example:
  m := [2:2, 3:3, 4:4]
  x := m.map |Int v->Int| { return v*2 }
  x => [2:4, 3:6, 4:8]

--------------------------------------------------------------------------------

(Method)
http://f...content-available-to-author-only...m.org/doc/sys/Range#map

sys
  Range
    map(|sys::Int->sys::Obj?| c)

Create a new list which is the result of calling c for
every integer in the range.  The new list is typed based on
the return type of c.

Example:
  (10..15).map |i->Str| { i.toHex }  =>  Str[a, b, c, d, e, f]

--------------------------------------------------------------------------------

(Method)
http://f...content-available-to-author-only...m.org/doc/web/WebSession#map

web
  WebSession
    map()

Application name/value pairs which are persisted
between HTTP requests.  The values stored in this
map must be serializable.

https://ideone.com/Rrwjx3

Tell Me About...

A small program that indexes and displays Fantom documentation.

language:

Fantom (fantom 1.0.72)

created:

visibility:

public

Share or Embed source code

Discover > Sphere Engine API

The brand new service which powers Ideone!

Discover > IDE Widget

Widget for compiling and running the source code in a web browser!

Discover > Sphere Engine API

Discover > IDE Widget

Choose your language