; van eck sequence

(define-syntax define-generator
  (lambda (x)
    (syntax-case x (lambda)
      ((stx name (lambda formals e0 e1 ...))
         (with-syntax ((yield (datum->syntax (syntax stx) 'yield)))
           (syntax (define name
             (lambda formals
               (let ((resume #f) (return #f))
                 (define yield
                   (lambda args
                     (call-with-current-continuation
                      (lambda (cont)
                        (set! resume cont)
                        (apply return args)))))
                 (lambda ()
                   (call-with-current-continuation
                    (lambda (cont)
                      (set! return cont)
                      (cond (resume (resume))
                      (else (let () e0 e1 ...)
                            (error 'name "unexpected return"))))))))))))
        ((stx (name . formals) e0 e1 ...)
          (syntax (stx name (lambda formals e0 e1 ...)))))))

(define (take-gen n gen)
  (let loop ((n n) (gs (list)))
    (if (zero? n) (reverse gs)
      (loop (- n 1) (cons (gen) gs)))))

(define-generator (van-eck)
  (let loop ((v 0) (i 0) (prev (list)))
    (yield v)
    (let ((t v))
      (let ((v (- i (cond ((assoc v prev) => cdr) (else i)))))
        (loop v (+ i 1) (cons (cons t i) prev))))))

(display (take-gen 25 (van-eck)))