fork download

copy

declare
proc {Sudoku P ?Grid}
   %% Creo la lista di 9 elementi, tutti UNBOUND inizialmente
   Grid = {List.make 9}
   %% Popola ogni elemento di Grid con un'altra lista, aventi 9 elementi con valore 1#9 (range di valori ammissibili del sudoku)
   {List.forAll Grid proc {$ Row} Row = {FD.list 9 1#9} end}
   %% Vincoli RIGA
   for I in 1..9 do
      {FD.distinct {Nth Grid I}} %% Nth estrae l'iesimo elemento da Grid, la distinct verifica che non si ripetano elementi
   end
   %% Vincoli COLONNA
   for J in 1..9 do
      {FD.distinct {List.map Grid fun {$ Row}
				     {Nth Row J}
				  end
		   }
      }
   end
   %% Vincoli BLOCCO
   for BI in 0..2 do
      for BJ in 0..2 do
	 Block = for I in 1..3 collect:Collect do
		    for J in 1..3 do
		       {Collect {Nth {Nth Grid (3*BI+I)} (3*BJ+J)}}
		    end
		 end
      in
	 {FD.distinct Block}
      end
   end
   %% Vincoli sui Valori
   {List.forAllInd P
    proc {$ Y R}
       Row = {Nth Grid Y}
    in
       {List.forAllInd R
	proc {$ X I}
	   if {Not {IsFree I}} then
	      {Nth Row X} :: I
	   end
	end
       }
    end
   }
   {FD.distribute ff {Flatten Grid}} %% la FD accetta solo LISTE semplici, e non liste di liste, quindi uso la Flatten su Grid
end
declare
Puzzle=[
	[_ _ _ 6 _ _ _ _ 4]
	[8 _ _ _ _ _ _ 7 _]
	[_ _ 5 _ _ 9 _ _ 3]
	[_ _ _ 8 _ _ 2 _ 1]
	[_ 9 _ _ _ _ _ 6 _]
	[4 _ 6 _ _ 3 _ _ _]
	[1 _ _ 2 _ _ 5 _ _]
	[_ 7 _ _ _ _ _ _ 8]
	[3 _ _ _ _ 4 _ _ _]
       ]
{Browse {Search.base.one proc{$ Sol} {Sudoku Puzzle Sol} end}}

Mozart Compiler 1.4.0 (20080704) playing Oz 3

%%% feeding file prog.oz

%********************* binding analysis error *******************
%**
%** variable FD not introduced
%**
%** in file "./prog.oz", line 6, column 41

%********************* binding analysis error *******************
%**
%** variable FD not introduced
%**
%** in file "./prog.oz", line 9, column 7

%********************* binding analysis error *******************
%**
%** variable FD not introduced
%**
%** in file "./prog.oz", line 13, column 7

%********************* binding analysis error *******************
%**
%** variable FD not introduced
%**
%** in file "./prog.oz", line 28, column 3

%********************* binding analysis error *******************
%**
%** variable FD not introduced
%**
%** in file "./prog.oz", line 45, column 4
%** ------------------ rejected (5 errors)

Standard output is empty